Min與MinA函數是 Excel 中用於求最小值的函數，前者用於求數值的最小值，後者用於求數值和邏輯值的最小值。它們都至少要有一個參數，最多隻能有 255 個參數。兩個函數既可以不加任何條件求最小值又可以用If函數與星號（*）求滿足指定條件的最小值。以下就是 Excel Min函數與MinA函數的求最小值的使用方法，共包含5個實例，求不爲0最小值、返回最小時間和用if加*組合多條件求最小值，實例操作所用版本均爲 Excel 2016。

一、Excel Min函數與MinA函數語法

（一）Min函數語法

表達式：MIN(Number1, [Number2], ...)

中文表達式：MIN(數值1, [數值2], ...)

（二）MinA函數語法

表達式：MINA(Value1,[Value2], ...)

中文表達式：MINA(值1,[值2], ...)

（三） Min函數與MinA函數異同點

Min函數與MinA函數的異同點與Max函數與MaxA函數的異同點一樣，可以參數上一篇《Excel Max與MaxA函數的使用方法與用if或*組合多條件求最大值實例》。

二、Excel Min與MinA函數使用的方法及實例

（一）Min函數的使用方法

1、選中 B1 單元格，輸入公式 =min(a1:A6)，按回車，返回最小值 5；選中 A4，按 Delete，把 5 刪除，B1 返回最小值 8；雙擊 A2，把 8 改爲 "8"，B1 返回最小值 10；選中 A4，輸入“二”，B1 返回最小值 10；選中 A4，輸入 false，B1 返回最小值 10；選中 A4，把 #VALUE! 複製到 A4，B1 返回值 #VALUE!；操作過程步驟，如圖1所示：

圖1

2、公式說明：

公式 =min(a1:A6) 用於返回 A1 至 A6 中的最小值；當把 A4 中的 5 刪除後，公式返回 8，說明Min函數忽略空單元格；當把 A2 的 8 改爲“8”後，公式返回 10，說明單元格中用雙引號括起來的數值被忽略；當在 A4 中輸入“二”後，公式返回 10，說明不能轉爲數值的文本被忽略；在 A4 輸入 false 後，公式仍返回 10，說明Min函數忽略單元格中的邏輯值；把 #VALUE! 複製到 A4 後，返回值錯誤 #VALUE!，說明單元格中有錯誤值，Min函數直接返回錯誤值。

（二）MinA函數的使用方法

1、雙擊 B1 單元格，把公式 =MINA(A1:A6,4) 複製到 B1，按回車，返回最小值 4；操作過程步驟，如圖2所示：

圖2

2、公式 =MINA(A1:A6,4) 返回最小值 4，說明MinA函數的參數可以同時爲不同類型，Min函數也一樣。

三、Excel Min函數的擴展應用實例

（一）用 Min + If 求不爲 0 的最小值

1、假如要求學生“高數”成績中不爲 0 的最低分。雙擊 C2 單元格，把公式 =MIN(IF(B2:B10>0,B2:B10)) 複製到 C2，按 Ctrl + Shift + 回車，返回不爲 0 的最小值 76；操作過程步驟，如圖3所示：

圖3

2、公式說明：

A、公式 =MIN(IF(B2:B10>0,B2:B10)) 是一個數組公式，因此要按 Ctrl + Shift + 回車。

B、B2:B10>0 是 If 的條件，意思是：如果 B2 至 B10 的值大於 0，返回 True，否則返回 False；例如第一次取 B2 中的值 76，它大於 0，所以返回 True，第二取 B3 中的值 80，它也大於 0，也返回 True；最後返回數組 {TRUE;TRUE;TRUE;FALSE;TRUE;TRUE;TRUE;TRUE;TRUE}。

C、B2:B10 返回數組 {76;80;91;0;87;86;83;87;83}，IF(B2:B10>0,B2:B10) 變爲

IF({TRUE;TRUE;TRUE;FALSE;TRUE;TRUE;TRUE;TRUE;TRUE},{76;80;91;0;87;86;83;87;83})，把兩個數組對應的元素相乘，返回結果 {76;80;91;FALSE;87;86;83;87;83}，相乘時，True 被當爲 1。

D、則公式變爲 =MIN({76;80;91;FALSE;87;86;83;87;83})，由於數組中的邏輯值不計入求最小值，所以返回最小值 76。

（二）返回最小時間

1、雙擊 B1 單元格，把公式 =MIN(--A1:A8) 複製到 B1，按 Ctrl + Shift + 回車，返回最小時間 9:12:35；操作過程步驟，如圖4所示：

圖4

2、公式說明：

公式 =MIN(--A1:A8) 中 -- 表示把時間轉爲數值，然後再求最小值。注意：B1 單元格的格式必須是時間類型，否則返回的可能是數值而不是時間。

（三）用 If 和 * 組合多條件求最小值

1、假如要求“產品名稱”爲“白色T恤”且銷量大於等於 800 的服裝最早銷量日期。雙擊 E2 單元格，把公式 =MIN(IF((A2:A11="白色T恤")*(D2:D11>=800),B2:B11)) 複製到 E2，按 Ctrl + Shift + 回車，返回服裝最早銷量日期 2018/9/10；操作過程步驟，如圖5所示：

圖5

2、公式 =MIN(IF((A2:A11="白色T恤")*(D2:D11>=800),B2:B11)) 說明：

A、(A2:A11="白色T恤") 是 If 的一個條件，意思是：如果 A2 至 A11 中爲“白色T恤”的返回 True，否則返回 False，最後返回 {TRUE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE}。

B、(D2:D11>=800) 是 If 的另一個條件，意思是：如果 D2 至 D11 中大於等於 800 的返回 True，否則返回 False，最後返回 {FALSE;FALSE;TRUE;FALSE;TRUE;TRUE;FALSE;TRUE;TRUE;TRUE}。

C、則 (A2:A11="白色T恤")*(D2:D11>=800) 變爲 {TRUE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE}*{FALSE;FALSE;TRUE;FALSE;TRUE;TRUE;FALSE;TRUE;TRUE;TRUE}，把兩個數組對應的元素相乘，最後返回 {0;0;1;0;0;1;0;0;0;0}，相乘時，True 被當爲 1、False 轉爲 0。

D、則公式變爲 =MIN(IF({0;0;1;0;0;1;0;0;0;0},B2:B11))，條件數組中爲 0 的返回 False、爲 1 的返回 B2 至 B11 對應的值，則公式變爲 =MIN({FALSE;FALSE;43353;FALSE;FALSE;43354;FALSE;FALSE;FALSE;FALSE})，最後求最小值返回 43353，轉爲日期就是 2018/9/10。

提示：E2 的單元格格式必須爲日期，否則顯示的不是日期而是數字。

3、不能把公式 =MIN(IF((A2:A11="白色T恤")*(D2:D11>=800),B2:B11)) 改爲 =MIN((A2:A11="白色T恤")*(D2:D11>=800)*(B2:B11))，它們不等價，後者會返回意外值 1900/1/0，如圖6所示：

圖6